! Mplus Program for fitting interaction model example appearing in 
! Wall MM (2009) Maximum likelihood and Bayesian estimation for 
! nonlinear structural equation models, in Handbook
! of Quantitative Methods in Pscychology eds Roger Millsap and 
! Alber Maydeu-Olivares.

Data:

file is "C:\file\dataexpb.dat";

  variable:
  names are dummy count y1-y9 iter;
  usevariables are y1-y9;
  idvariable = count;

Analysis: 
type = random;
algorithm = integration;

Model: 

! putting [y7@0 y8@0 y9@0] fixes the intercept for the y7, y8, y9 variables
! in the measurment model to zero, the other measurement model intercepts
! are estimated and are called the NU parameters in the output

! putting [f1*1 f2*1] tells Mplus to estimate a mean for f1 and f2
! and use 1 as the starting value, putting [f3*1] tells Mplus to estimate
! an intercept for the structural model of f3 on f1 f2 and f1xf2
 
       f1 by y7 y1 y2; [y7@0] ;  
       f2 by y8 y3 y4 ; [y8@0] ; 
       f3 by y9 y5 y6 ; [y9@0] ; 

       f1xf2 | f1 xwith f2;

       f3 on f1 f2 f1xf2;
        
       [f1* f2* f3*];


output: tech1 tech8 standardized;
       
SAVEDATA:
file is "C:\file\fscores.dat"; 
save = fscores;